BAT脚本:一键获取电脑主要硬件配置信息并自动生成记录文件

2,932次阅读
9条评论

热帖最近遇到个IT基础搞的很糟糕的企业,IT资产管理、IP-Mac绑定之类的那是一概没有做,头大如牛。用局域网扫描工具,IP、Mac地址信息还是很容易获取到,那怎么和员工信息进行绑定呢?没有部署AD域,也没有安装任何桌管软件,策略推送或者用软件自动提取员工终端数据是不可能的了,还好用户不多,挨个跑去查看登记吧。

一、bat需求:

1、获取电脑上主要硬件的厂商、版本、规格等信息;

2、尽量简单,用户双击运行产生结果;

3、记录文件自动存放到bat所在路径。

优化:为方便批量下载记录文件不出现文件名冲突,在用户端运行bat时要求输入用户名,然后在记录文件名称中包含用户名以作区分。

二、bat代码详细:

@echo off & title 获取本机简要配置信息

::自定义用户名
set /p names=请输入用户名:
::设置信息保存路径
set Upath=%~dp0
echo 检测当前U盘路径:%Upath%
set Log="%Upath%"本机简要配置信息(%names%).txt

::计算机主要硬件信息获取
echo WScript.Echo Wscript.Arguments(0) / (1024 * 1024 * 1024)>Calculation.vbs
echo 正在获取信息中 ...
::执行结果写入Log文件
(echo 登 录 名:%USERNAME%
echo 计算机名:%COMPUTERNAME%
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Name /value ^| findstr /i "Name"') do echo 电脑型号:%%~a
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Vendor /value ^| findstr /i "Vendor"') do echo 制 造 商:%%~a
for /f "tokens=2 delims==" %%a in ('wmic csproduct get IdentifyingNumber /value ^| findstr /i "IdentifyingNumber"') do echo SN序列号:%%~a
for /f "tokens=2 delims==" %%a in ('wmic cpu get Name /value ^| findstr /i "Name"') do echo 处 理 器:%%~a
for /f "tokens=2 delims==" %%a in ('wmic memorychip get Capacity /value ^| findstr /i "Capacity"') do (
for /f "tokens=1 delims=." %%b in ('cscript /nologo Calculation.vbs "%%~a"') do set /a m+=%%~b
)
call echo 内存容量:%%m%% GB
echo.
set /a k=0
for /f "tokens=2 delims==" %%a in ('wmic DiskDrive get Size /value ^| findstr /i "Size"') do (
for /f "tokens=1 delims=." %%b in ('cscript /nologo Calculation.vbs "%%~a"') do set /a d+=%%~b && set /a t=%%~b&&set /a k=k+1
call echo 硬盘%%k%%容量:%%t%% GB
)
call echo 硬盘总容量:%%d%% GB
echo.
for /f "tokens=2 delims==" %%a in ('wmic nic where "netconnectionid!=NULL" get macaddress /value ^| findstr /i "MACAddress"') do echo MAC 地址:%%~a)>"%Log%"
del Calculation.vbs
echo 信息获取,并保存。
pause

三、执行结果:

将bat文件拖到任意路径下双击执行,在该目录下都将自动生成计算机硬件配置信息记录文件:

BAT脚本:一键获取电脑主要硬件配置信息并自动生成记录文件

P1.bat脚本任意路径下自动生成本机主要硬件配置信息

附:

 此处含有隐藏内容,请提交评论并审核通过刷新后即可查看!
正文完
 
itylq
版权声明:本站原创文章,由 itylq 2022-09-19发表,共计1678字。
转载说明:本站文章遵循CC-4.0国际许可协议,转载请注明出处(格式如“来源:IT摇篮曲www.itylq.com")。
评论(9条评论)
jianboliangcha 评论达人 LV.1
2023-10-10 09:08:36 回复

支持,刚好很需要这个做公司资产登记

 Windows  Chrome  中国广东省肇庆市电信
sls 评论达人 LV.1
2023-08-04 14:37:17 回复

感谢分享,支持一下

 Windows  Chrome  中国贵州省遵义市电信
tag 评论达人 LV.1
2023-08-02 09:50:26 回复

支持

 Windows  Chrome  中国上海上海市电信
chenrj1989 评论达人 LV.1
2023-06-08 14:12:57 回复

看看能不能用

 Windows  Chrome  中国福建省福州市电信
youqu2008 评论达人 LV.1
2023-04-10 23:30:09 回复

如果可以必须支持一下

 Windows  Chrome  中国北京北京市移动
白小杰 评论达人 LV.1
2023-03-17 21:03:32 回复

必须测试一下效果,好东西

 Windows  Chrome  中国湖北省武汉市移动
3093 评论达人 LV.1
2023-03-12 22:53:54 回复

dddd查看下

 Windows  Chrome  中国广东省广州市电信
1072 评论达人 LV.1
2023-03-03 14:23:40 回复

kankan

 Windows  Chrome  中国上海上海市联通
    nick 评论达人 LV.1
    2023-09-13 11:50:38 回复

    @1072 正好需要这个

     Windows  Chrome  波兰